2.6 Creating user keywords

Keyword tables are used to create new higher-level keywords by combining existing keywords together. These keywords are called user keywords to differentiate them from lowest level library keywords that are implemented in test libraries. The syntax for creating user keywords is very close to the syntax for creating test cases, which makes it easy to learn.

2.6.1 User keyword syntax

Basic syntax

In many ways, the overall user keyword syntax is identical to the test case syntax. User keywords are created in keyword tables which differ from test case tables only by the name that is used to identify them. User keyword names are in the first column similarly as test cases names. Also user keywords are created from keywords, either from keywords in test libraries or other user keywords. Keyword names are normally in the second column, but when setting variables from keyword return values, they are in the subsequent columns.

User keyword examples
Keyword	Action	Argument	Argument
Open Login Page	Open Browser	http://host/login.html
	Title Should Be	Login Page

Title Should Start With	[Arguments]	${expected}
	${title} =	Get Title
	Should Start With	${title}	${expected}

Most user keywords take some arguments. This important feature is used already in the second example above, and it is explained in detail later in this section, similarly as user keyword return values.

User keywords can be created in test case files, resource files, and test suite initialization files. Keywords created in resource files are available for files using them, whereas other keywords are only available in the files where they are created.

Settings in the Keyword table

User keywords can have similar settings as test cases, and they have the same square bracket syntax separating them from keyword names. All available settings are listed below and explained later in this section.

[Documentation]

Used for setting a user keyword documentation.

[Arguments]

Specifies user keyword arguments.

[Return]

Specifies user keyword return values.

[Teardown]

Specify user keyword teardown. Available from Robot Framework 2.6 onwards.

[Timeout]

Sets the possible user keyword timeout. Timeouts are discussed in a section of their own.

2.6.2 User keyword name and documentation

The user keyword name is defined in the first column of the user keyword table. Of course, the name should be descriptive, and it is acceptable to have quite long keyword names. Actually, when creating use-case-like test cases, the highest-level keywords are often formulated as sentences or even paragraphs.

User keywords can have a documentation that is set with the [Documentation] setting, exactly as test case documentation. This setting documents the user keyword in the test data. It is also shown in a more formal keyword documentation, which the libdoc tool can create from resource files. Finally, the first row of the documentation is shown as a keyword documentation in test logs.

Sometimes keywords need to be removed, replaced with new ones, or deprecated for other reasons. User keywords can be marked deprecated by starting the documentation with DEPRECATED, which will cause a warning when the keyword is used. For more information, see Deprecating keywords section.

2.6.3 User keyword arguments

Most user keywords need to take some arguments. The syntax for specifying them is probably the most complicated feature normally needed with Robot Framework, but even that is relatively easy, particularly in most common cases. Arguments are normally specified with the _[Arguments]_setting, and argument names use the same syntax as variables, for example ${arg}.

Positional arguments

The simplest way to specify arguments (apart from not having them at all) is using only positional arguments. In most cases, this is all that is needed.

The syntax is such that first the [Arguments] setting is given and then argument names are defined in the subsequent cells. Each argument is in its own cell, using the same syntax as with variables. The keyword must be used with as many arguments as there are argument names in its signature. The actual argument names do not matter to the framework, but from users' perspective they should be as descriptive as possible. It is recommended to use lower-case letters in variable names, either as ${my_arg}, ${my arg} or ${myArg}.

User keyword taking different number of arguments
Keyword	Action	Argument	Argument	Argument
One Argument	[Arguments]	${arg_name}
	Log	Got argument ${arg_name}

Three Arguments	[Arguments]	${arg1}	${arg2}	${arg3}
	Log	1st argument: ${arg1}
	Log	2nd argument: ${arg2}
	Log	3rd argument: ${arg3}

Default values with user keywords

When creating user keywords, positional arguments are sufficient in most situations. It is, however, sometimes useful that keywords have default values for some or all of their arguments. Also user keywords support default values, and the needed new syntax does not add very much to the already discussed basic syntax.

In short, default values are added to arguments, so that first there is the equals sign (=) and then the value, for example ${arg}=default. There can be many arguments with defaults, but they all must be given after the normal positional arguments. The default value can contain a variable created on suite or global scope.

Note

The syntax for default values is space sensitive. Spaces before the = sign are not allowed, and possible spaces after it are considered part of the default value itself.

User keyword with default values for arguments
Keyword	Action	Argument	Argument
One Argument With Default Value	[Arguments]	${arg}=default value
	[Documentation]	This keyword takes	0-1 arguments
	Log	Got argument ${arg}

Two Arguments With Defaults	[Arguments]	${arg1}=default 1	${arg2}=${VARIABLE}
	[Documentation]	This keyword takes	0-2 arguments
	Log	1st argument ${arg1}
	Log	2nd argument ${arg2}

One Required And One With Default	[Arguments]	${required}	${optional}=default
	[Documentation]	This keyword takes	1-2 arguments
	Log	Required: ${required}
	Log	Optional: ${optional}

When a keyword accepts several arguments with default values and only some of them needs to be overridden, it is often handy to use the named arguments syntax. When this syntax is used with user keywords, the arguments are specified without the ${} decoration. For example, the second keyword above could be used like below and ${arg1} would still get its default value.

User keyword and named arguments syntax
Test Case	Action	Argument	Argument
Example	Two Arguments With Defaults	arg2=new value

As all Pythonistas must have already noticed, the syntax for specifying default arguments is heavily inspired by Python syntax for function default values.

Varargs with user keywords

Sometimes even default values are not enough and there is a need for a keyword accepting variable number of arguments. User keywords support also this feature. All that is needed is having list variable such as @{varargs} as the last argument in the keyword signature. This syntax can be combined with the previously described positional arguments and default values, and at the end the list variable gets all the leftover arguments that do not match other arguments. The list variable can thus have any number of items, even zero.

User keywords accepting variable number of arguments
Keyword	Action	Argument	Argument	Argument
Any Number Of Arguments	[Arguments]	@{varargs}
	Log Many	@{varargs}

One Or More Arguments	[Arguments]	${required}	@{rest}
	Log Many	${required}	@{rest}

Required, Default, Varargs	[Arguments]	${req}	${opt}=42	@{others}
	Log	Required: ${req}
	Log	Optional: ${opt}
	Log	Others:
	: FOR	${item}	IN	@{others}
		Log	${item}

Notice that if the last keyword above is used with more than one argument, the second argument ${opt} always gets the given value instead of the default value. This happens even if the given value is empty. The last example also illustrates how a variable number of arguments accepted by a user keyword can be used in a for loop. This combination of two rather advanced functions can sometimes be very useful.

Again, Pythonistas probably notice that the variable number of arguments syntax is very close to the one in Python.

2.6.4 Embedding arguments into keyword name

Robot Framework has also another approach to pass arguments to user keywords than specifying them in cells after the keyword name as explained in the previous section. This method is based on embedding the arguments directly into the keyword name, and its main benefit is making it easier to use real and clear sentences as keywords.

Basic syntax

It has always been possible to use keywords like Select dog from list and Selects cat from list, but all such keywords must have been implemented separately. The idea of embedding arguments into the keyword name is that all you need is a keyword with name like Select ${animal} from list.

Ex2.6.4.1

An example keyword with arguments embedded into its name
Keyword	Action	Argument	Argument
Select ${animal} from list	Open Page	Pet Selection
	Select Item From List	animal_list	${animal}

Keywords using embedded arguments cannot take any "normal" arguments (specified with [Arguments] setting) but otherwise they are created just like other user keywords. The arguments used in the name will naturally be available inside the keyword and they have different value depending on how the keyword is called. For example, ${animal} in the previous has value dog if the keyword is used like Select dog from list. Obviously it is not mandatory to use all these arguments inside the keyword, and they can thus be used as wildcards.

These kind of keywords are also used the same way as other keywords except that spaces and underscores are not ignored in their names. They are, however, case-insensitive like other keywords. For example, the keyword in the example above could be used like select x from list, but not likeSelect x fromlist.

Embedded arguments do not support default values or variable number of arguments like normal arguments do. Using variables when calling these keywords is possible but that can reduce readability. Notice also that embedded arguments only work with user keywords.

Embedded arguments matching too much

One tricky part in using embedded arguments is making sure that the values used when calling the keyword match the correct arguments. This is a problem especially if there are multiple arguments and characters separating them may also appear in the given values. For example, keywordSelect ${city} ${team} does not work correctly if used with city containing too parts like Select Los Angeles Lakers.

An easy solution to this problem is quoting the arguments (e.g. Select "${city}" "${team}") and using the keyword in quoted format (e.g. Select "Los Angeles" "Lakers"). This approach is not enough to resolve all this kind of conflicts, though, but it is still highly recommended because it makes arguments stand out from rest of the keyword. A more powerful but also more complicated solution, using custom regular expressions when defining variables, is explained in the next section. Finally, if things get complicated, it might be a better idea to use normal positional arguments instead.

The problem of arguments matching too much occurs often when creating keywords that ignore given/when/then/and/but prefixes . For example, ${name} goes home matches Given Janne goes home so that ${name} gets value Given Janne. Quotes around the argument, like in "${name}" goes home, resolve this problem easily.

Using custom regular expressions

When keywords with embedded arguments are called, the values are matched internally using regular expressions (regexps for short). The default logic goes so that every argument in the name is replaced with a pattern .*? that basically matches any string. This logic works fairly well normally, but as just discussed above, sometimes keywords match more than intended. Quoting or otherwise separating arguments from the other text can help but, for example, the test below fails because keyword I execute "ls" with "-lh" matches both of the defined keywords.

Embedded arguments match too much
Test Case	Step
Example	I execute "ls"
	I execute "ls" with "-lh"

Keyword	Action	Argument	Argument
I execute "${cmd}"	Run	${cmd}
I execute "${cmd}" with "${opts}"	Run	${cmd} ${opts}

A solution to this problem is using a custom regular expression that makes sure that the keyword matches only what it should in that particular context. To be able to use this feature, and to fully understand the examples in this section, you need to understand at least the basics of the regular expression syntax.

A custom embedded argument regular expression is defined after the base name of the argument so that the argument and the regexp are separated with a colon. For example, an argument that should match only numbers can be defined like ${arg:\d+}. Using custom regular expressions is illustrated by the examples below.

Using custom regular expressions with embedded arguments
Test Case	Step
Example	I execute "ls"
	I execute "ls" with "-lh"
	I type 1 + 2
	I type 53 - 11
	Today is 2011-06-27

Keyword	Action	Argument	Argument	Argument
I execute "${cmd:^"+}"	Run	${cmd}
I execute "${cmd}" with "${opts}"	Run	${cmd} ${opts}
I type ${a:\d+} ${operator:[+-]} ${b:\d+}	Calculate	${a}	${operator}	${b}
Today is ${date:\d{4}-\d{2}-\d{2}}	Log	${date}

In the above example keyword I execute "ls" with "-lh" matches only I execute "${cmd}" with "${opts}". That is guaranteed because the custom regular expression ^"+ in I execute "${cmd:^"}" means that a matching argument cannot contain any quotes. In this case there is no need to add custom regexps to the other I execute variant.

Tip

If you quote arguments, using regular expression ^"+ guarantees that the argument matches only until the first closing quote.

Supported regular expression syntax

Being implemented with Python, Robot Framework naturally uses Python's re module that has pretty standard regular expressions syntax. This syntax is otherwise fully supported with embedded arguments, but regexp extensions in format (?...) cannot be used. Notice also that matching embedded arguments is done case-insensitively. If the regular expression syntax is invalid, creating the keyword fails with an error visible in test execution errors.

Escaping special characters

There are some special characters that need to be escaped when used in the custom embedded arguments regexp. First of all, possible closing curly braces (}) in the pattern need to be escaped with a single backslash (}) because otherwise the argument would end already there. This is illustrated in the previous example with keyword Today is ${date:\d{4}-\d{2}-\d{2}}.

Backslash () is a special character in Python regular expression syntax and thus needs to be escaped if you want to have a literal backslash character. The safest escape sequence in this case is four backslashes (\\) but, depending on the next character, also two backslashes may be enough.

Notice also that keyword names and possible embedded arguments in them should not be escaped using the normal test data escaping rules. This means that, for example, backslashes in expressions like ${name:\w+} should not be escaped.

| | | --- |

2.6 Creating user keywords